extends Spatial

signal game_over
signal got_treasure(item_type)

const LootTable = preload("res://scripts/loot_table.gd")
const RockScene = preload("res://scenes/rock.tscn")

onready var timer : Timer = $Timer

export var play_time: float = 20.0
export (Array,Resource) var loot_items = []
export (Array,int) var loot_weights = []

var loot_table = null

func _ready():
	loot_table = LootTable.new(loot_items, loot_weights)
	timer.start(play_time)
	spawn_rocks(10)

func spawn_rocks(count: int):
	var locations: Array = get_tree().get_nodes_in_group("rock_spawn_location")
	locations.shuffle()
	for i in range(min(count, locations.size())):
		var location = locations[i]
		var rock = RockScene.instance()
		rock.treasure = loot_table.roll_for_loot()
		assert(rock.treasure != null)
		location.add_child(rock)

func _on_collection_area_area_entered(area):
	if area.has_meta("owner"):
		area = area.get_meta("owner")
	emit_signal("got_treasure", area.treasure)
	area.queue_free()

func _process(delta):
	$"%progress_bar".value = timer.time_left * 100.0 / timer.wait_time

func _on_Timer_timeout():
	emit_signal("game_over")