Add rover game and such

scripts/rover_station/rover_station.gd

@@ -0,0 +1,41 @@
+extends Damageable
+
+const StateIdle = preload("res://scripts/rover_station/state/idle.gd")
+const StateBroken = preload("res://scripts/rover_station/state/broken.gd")
+const StatePlaying = preload("res://scripts/rover_station/state/playing.gd")
+
+var state = null
+var treasure := [] # array of ItemTypes
+
+func _ready():
+	state = StateBroken.new() if start_broken else StateIdle.new()
+	state.ctx = self
+	state.enter_from(null)
+	print("rover_station: NULL -> ", state.NAME)
+
+func change_state(new_state):
+	print("rover_station: ", state.NAME, " -> ", new_state.NAME)
+	new_state.ctx = self
+	state.exit_to(new_state)
+	new_state.enter_from(state)
+	state = new_state
+
+func _on_coin_machine_coin_requirement_met(player):
+	state.on_coin_machine_coin_requirement_met(player)
+
+func _on_item_dump_completed():
+	state.on_item_dump_completed()
+
+func on_player_sleep():
+	state.on_player_sleep()
+
+func add_treasure(item_type: Resource):
+	if $item_holder.item_in_hold == null:
+		$item_holder.add_item(item_type.spawn_node())
+	else:
+		treasure.push_back(item_type)
+
+func _on_item_holder_item_changed(item):
+	if item == null and not treasure.empty():
+		$item_holder.add_item(treasure.pop_front().spawn_node())
+

scripts/rover_station/state/broken.gd

@@ -0,0 +1,33 @@
+extends Reference
+
+const INTERFACES = [preload("res://scripts/rover_station/state/state_interface.tres")]
+const NAME = "broken"
+
+var ctx = null
+
+func _init():
+	pass
+
+func enter_from(state):
+	ctx.get_node("item_dump").enabled = true
+	ctx.get_node("item_dump").reset()
+	ctx.get_node("coin_machine").enabled = false
+	ctx.get_node("item_holder").add_enabled = true
+	ctx.get_node("item_holder").remove_enabled = true
+	ctx.get_node("status_light").fail()
+
+func exit_to(state):
+	assert(state.NAME != "broken")
+
+func on_coin_machine_coin_requirement_met(player):
+	assert(false, "should be impossible while broken")
+
+func on_item_dump_completed():
+	ctx.full_heal()
+	ctx.change_state(ctx.StateIdle.new())
+
+func on_damage_taken():
+	assert(false, "should be impossible while broken")
+
+func on_player_sleep():
+	ctx.treasure.clear()

scripts/rover_station/state/idle.gd

@@ -0,0 +1,32 @@
+extends Reference
+
+const INTERFACES = [preload("res://scripts/rover_station/state/state_interface.tres")]
+const NAME = "idle"
+
+var ctx = null
+
+func _init():
+	pass
+
+func enter_from(state):
+	ctx.get_node("item_dump").enabled = false
+	ctx.get_node("coin_machine").enabled = true
+	ctx.get_node("item_holder").add_enabled = true
+	ctx.get_node("item_holder").remove_enabled = true
+	ctx.get_node("status_light").idle()
+
+func exit_to(state):
+	pass
+
+func on_coin_machine_coin_requirement_met(player):
+	ctx.change_state(ctx.StatePlaying.new(player))
+
+func on_item_dump_completed():
+	assert(false, "item dump should be disabled")
+
+func on_damage_taken():
+	if ctx.hp <= 0:
+		ctx.change_state(ctx.StateBroken.new())
+
+func on_player_sleep():
+	ctx.treasure.clear()

scripts/rover_station/state/playing.gd

@@ -0,0 +1,52 @@
+extends Reference
+
+const INTERFACES = [preload("res://scripts/rover_station/state/state_interface.tres")]
+const NAME = "playing"
+
+var ctx: Spatial = null
+var game: Node
+var player: Node
+
+func _init(p_player: Node):
+	player = p_player
+
+func enter_from(state):
+	ctx.get_node("item_dump").enabled = false
+	ctx.get_node("coin_machine").enabled = false
+	ctx.get_node("item_holder").add_enabled = false
+	ctx.get_node("item_holder").remove_enabled = false
+	ctx.get_node("status_light").activate()
+	# START THE GAME
+	game = ctx.get_node("%rover_game").create_instance()
+	game.connect("got_treasure", self, "on_got_treasure")
+	game.connect("game_over", self, "on_game_over")
+	ctx.get_node("game_canvas").visible = true
+	player.start_playing_rover_game()
+
+func exit_to(state):
+	# END THE GAME
+	player.stop_playing_rover_game()
+	ctx.get_node("game_canvas").visible = false
+	if game:
+		game.queue_free()
+	game = null
+
+func on_coin_machine_coin_requirement_met(player):
+	assert(false, "coin machine should be disabled while playing")
+
+func on_item_dump_completed():
+	assert(false, "item dump should be disabled while playing")
+
+func on_damage_taken():
+	if ctx.hp <= 0:
+		ctx.change_state(ctx.StateBroken.new())
+
+func on_got_treasure(treasure: Resource):
+	ctx.add_treasure(treasure)
+
+func on_game_over():
+	ctx.change_state(ctx.StateIdle.new())
+
+func on_player_sleep():
+	ctx.treasure.clear()
+	ctx.change_state(ctx.StateIdle.new())

scripts/rover_station/state/state_interface.tres

@@ -0,0 +1,7 @@
+[gd_resource type="Resource" load_steps=2 format=2]
+
+[ext_resource path="res://scripts/Interface.gd" type="Script" id=1]
+
+[resource]
+script = ExtResource( 1 )
+method_names = [ "enter_from", "exit_to", "on_coin_machine_coin_requirement_met", "on_item_dump_completed", "on_player_sleep" ]