Add food and yam interaction

scripts/hydroponics_station/hydroponics_station.gd

@@ -0,0 +1,32 @@
+extends Spatial
+
+const StateIdle = preload("res://scripts/hydroponics_station/state/idle.gd")
+const StateGrowing = preload("res://scripts/hydroponics_station/state/growing.gd")
+const StateBlocked = preload("res://scripts/hydroponics_station/state/blocked.gd")
+
+export var grow_time: float = 2.0
+var state = null
+
+func _ready():
+	$grow_timer.wait_time = grow_time
+
+	state = StateIdle.new()
+	state.ctx = self
+	state.enter_from(null)
+	print("hydroponics_station: NULL -> ", state.NAME)
+
+func change_state(new_state):
+	print("hydroponics_station: ", state.NAME, " -> ", new_state.NAME)
+	new_state.ctx = self
+	state.exit_to(new_state)
+	new_state.enter_from(state)
+	state = new_state
+
+func _on_coin_machine_coin_requirement_met(player):
+	state.on_coin_machine_coin_requirement_met(player)
+
+func _on_grow_timer_timeout():
+	state.on_grow_timer_timeout()
+
+func _on_item_holder_item_changed(item):
+	state.on_item_holder_item_changed(item)

scripts/hydroponics_station/state/blocked.gd

@@ -0,0 +1,25 @@
+extends Reference
+
+const NAME = "blocked"
+
+var ctx = null
+
+func _init():
+	pass
+
+func enter_from(state):
+	ctx.get_node("coin_machine").enabled = false
+	ctx.get_node("item_holder").add_enabled = true
+
+func exit_to(state):
+	pass
+
+func on_coin_machine_coin_requirement_met(player):
+	assert(false)
+
+func on_grow_timer_timeout():
+	assert(false)
+
+func on_item_holder_item_changed(item):
+	if item == null:
+		ctx.change_state(ctx.StateIdle.new())

scripts/hydroponics_station/state/growing.gd

@@ -0,0 +1,30 @@
+extends Reference
+
+const NAME = "growing"
+const raw_yam = preload("res://item_types/raw_yam.tres")
+
+var ctx = null
+var mat: SpatialMaterial = SpatialMaterial.new()
+
+func _init():
+	mat.albedo_color = Color.green
+
+func enter_from(state):
+	ctx.get_node("coin_machine").enabled = false
+	ctx.get_node("item_holder").add_enabled = false
+	ctx.get_node("grow_timer").start()
+	ctx.get_node("MeshInstance").set_surface_material(0, mat)
+
+func exit_to(state):
+	ctx.get_node("MeshInstance").set_surface_material(0, null)
+
+func on_coin_machine_coin_requirement_met(player):
+	assert(false, "coin machine should be disabled while growing")
+
+func on_grow_timer_timeout():
+	var item_holder = ctx.get_node("item_holder")
+	item_holder.spawn_item(raw_yam)
+	ctx.change_state(ctx.StateBlocked.new())
+
+func on_item_holder_item_changed(item):
+	assert(item.item_type == raw_yam)

scripts/hydroponics_station/state/idle.gd

@@ -0,0 +1,25 @@
+extends Reference
+
+const NAME = "idle"
+
+var ctx = null
+
+func _init():
+	pass
+
+func enter_from(state):
+	ctx.get_node("coin_machine").enabled = true
+	ctx.get_node("item_holder").add_enabled = true
+
+func exit_to(state):
+	pass
+
+func on_coin_machine_coin_requirement_met(player):
+	ctx.change_state(ctx.StateGrowing.new())
+
+func on_grow_timer_timeout():
+	assert(false, "grow timer shouldn't trigger while idle")
+
+func on_item_holder_item_changed(item):
+	assert(item != null)
+	ctx.change_state(ctx.StateBlocked.new())